2. ドキュメント型

← 言語 · 目次 · 次：text:: →

すべてのスクリプトは doc 変数を自動的に受け取ります。これが解析対象の PDF です。ここからページ、フォント、画像にたどり着きます。

2.1 doc — ドキュメント

プロパティ

check "Document properties" {
  print("file:", doc.filename)
  print("pages:", doc.page_count)
  print("title:", doc.title)

  // コレクションは通常のリストです — すべてのリストメソッドが使えます
  require doc.pages.length == doc.page_count
  require doc.fonts.length > 0
  print("images in the whole document:", doc.images.length)
}

メソッド

doc.extract_text()

ドキュメント全体のテキスト。ページは改行で区切られます。

check "Document text" {
  text = doc.extract_text()
  assert text.trim() != "", "PDF has no extractable text (images only?)"
  require text.contains("Agreement")
  print("total characters:", text.length)
}

2.2 page — ページ

ページは doc.pages（ブロック内）または page 変数（rule 内）から得ます。

プロパティ

check "Page format" {
  doc.pages.each { |page|
    // number は人が見る番号、index は内部計算用
    assert page.width > 100mm,
      "page #{page.number} is too narrow: #{page.width}pt"

    // ボックス：印刷には必須です
    assert page.has_trim_box,
      "page #{page.number} has no TrimBox (trim area)"
    assert page.has_bleed_box,
      "page #{page.number} has no BleedBox (bleed area)"
  }
}

check "Ink and strokes" {
  doc.pages.each { |page|
    assert page.tac <= 300,
      "page #{page.number}: #{page.tac}% ink (limit 300%)"

    // min_stroke_width は null になり得ます（線の無いページ）。
    // null は偽なので、この書き方は安全です：
    assert !page.min_stroke_width || page.min_stroke_width >= 0.25,
      "page #{page.number} has a hairline stroke"
  }
}

メソッド

page.extract_text()

このページだけのテキスト。

check "Blank pages" {
  blank = doc.pages.filter { |p| p.extract_text().trim() == "" }
  assert blank.length == 0,
    "#{blank.length} blank page(s): #{blank.map { |p| p.number }.join(", ")}"
}

2.3 font — フォント

フォントは doc.fonts から得ます。

check "Embedded fonts" {
  // 埋め込まれていないフォントはリーダーが代替します — 見た目が変わります
  doc.fonts.each { |font|
    assert font.is_embedded,
      "font '#{font.name}' is not embedded in the PDF"
  }
}

check "Font report" {
  print("fonts in use:", doc.fonts.map { |f| f.name }.join(", "))
  missing = doc.fonts.filter { |f| !f.is_embedded }
  print("not embedded:", missing.length)
}

2.4 image — 画像

画像は doc.images（全体）または page.images（1ページ分）から得ます。

DPI は実効値です。ピクセル数 ÷ ページ上の印刷サイズで計算され、 メタデータの公称値ではありません。印刷品質に効くのはこちらです。1000 px の画像を 20 cm に引き伸ばせば、メタデータが何と言おうと DPI は低くなります。

profile "images-for-offset" {
  const MIN_DPI = 300

  check "Resolution" {
    doc.images.each { |img|
      assert img.dpi >= MIN_DPI,
        "image #{img.width}x#{img.height}px on page #{img.page_number}: #{img.dpi} DPI (minimum #{MIN_DPI})"
    }
  }

  check "Color space" {
    // オフセット印刷は CMYK です。RGB は変換が必要です
    doc.images.each { |img|
      assert img.color_space != "DeviceRGB",
        "RGB image on page #{img.page_number} — convert to CMYK"
    }
  }

  check "Images per page" {
    doc.pages.each { |page|
      // page.images はそのページの画像だけを持ちます
      print("page", page.number, "has", page.images.length, "image(s)")
    }
  }
}

2.5 region — ページ上の領域

領域は矩形でページの一部を指定し、フッター、ヘッダー、バーコード欄、医薬品の 表示帯などを個別に検証できます。

作成

// region(x, y, 幅, 高さ [, "名前"])
// 原点 (0,0) は PDF と同じく左下です。
header = region(0, 742, 595, 100, "header")
footer = region(0, 0, 595, 60, "footer")
band = region(20mm, 250mm, 60mm, 15mm, "red band")

プロパティ

メソッド

check "Working with regions" {
  footer = region(0, 0, 595, 60, "footer")

  require footer.name == "footer"
  require footer.top == 60.0
  require footer.right == 595.0
  require footer.area == 35700.0

  // 点がフッター内にあるか
  require footer.contains_point(300, 30)
  require !footer.contains_point(300, 500)

  // 重なり：要素が禁止領域に侵入していないかの確認に使えます
  header = region(0, 780, 595, 62)
  require !footer.intersects(header)

  // expand/inset は「新しい」領域を返します（元は変わりません）
  slack = footer.expand(5mm)      // 各辺 5mm 広い
  safe = footer.inset(3mm)        // 各辺 3mm 狭い
  require slack.area > footer.area
  require safe.area < footer.area
}

検証での使い方

profile "medicine-label" {

  check "Prescription band" {
    // 表示帯は上部にあり、法定文言を含む必要があります
    band = region(0, 700, 595, 142, "band")
    content = text::extract_from_region(1, band)
    assert content.contains("PRESCRIPTION ONLY"),
      "band is missing the mandatory text"
  }

  check "Ink in the fold area" {
    // 折り目のインクが多すぎると加工で割れます
    fold = region(290, 0, 15, 842, "center fold")
    measured = prepress::calculate_tac_by_region(1, fold)
    assert measured.first() < 240,
      "too much ink on the fold: #{measured.first()}%"
  }

  check "Barcode in the right place" {
    code_area = region(400, 20, 180, 80, "barcode area")
    assert codes::validate_barcode_position(code_area),
      "barcode outside the reserved area"
  }
}

← 言語 · 目次 · 次：text:: →