7. `codes::` 名前空間 — バーコードと QR コード

← prepress:: · 目次 · 次：fix:: →

ドキュメントに印刷されたバーコードと QR コードを検出・デコード・検証する13の関数。

スキャンはページを高解像度でレンダリングし、いずれかの codes:: 関数を最初に使ったときに一度だけ実行されます。この名前空間を使わないスクリプトはその負荷を負いません。

対応形式：EAN-8/13、UPC-A/E、Code 128、Code 39、ITF、QR コード、Data Matrix、 Aztec、PDF417 など。

7.1 検出

関数	動作
`codes::detect_barcodes()`	バーコードがあれば真
`codes::detect_qrcodes()`	QR コードがあれば真
`codes::count_barcodes()`	検出されたコードの総数
`codes::get_barcode_type(n)`	n番目の形式（`"EAN_13"`、`"QR_CODE"`…）
`codes::get_barcode_location(n)`	位置 `[ページ, x, y]`（ポイント、左下原点）

check "Codes present" {
  assert codes::detect_barcodes(), "no barcode found in the artwork"
  assert codes::detect_qrcodes(), "the traceability QR code is missing"

  total = codes::count_barcodes()
  assert total == 2, "expected 2 codes (EAN + QR), found #{total}"

  kind = codes::get_barcode_type(1)
  assert kind == "EAN_13", "the main code should be EAN-13, it is #{kind}"

  spot = codes::get_barcode_location(1)
  assert spot.first() == 1, "barcode is not on the cover"
}

7.2 デコードと検証

関数	動作
`codes::decode_barcode(n)`	n番目のコードの内容
`codes::validate_barcode_checksum(n)`	n番目の GTIN チェックディジット
`codes::validate_gtin(text)` / `codes::validate_ean(text)`	文字列の GTIN チェックディジット
`codes::validate_code128()`	Code 128 が正常にデコードできれば真

check "Code integrity" {
  code = codes::decode_barcode(1)
  print("code read:", code)

  // チェックディジットが誤った GTIN はレジで弾かれます
  assert codes::validate_barcode_checksum(1),
    "invalid check digit in code #{code}"
  assert code.starts_with("789"),
    "GTIN is not Brazilian (should start with 789): #{code}"

  // バーの下に印刷された数字の確認
  printed = text::extract_from_region(1, region(400, 20, 180, 15)).trim()
  assert codes::validate_ean(printed),
    "the printed number is not a valid GTIN: #{printed}"
}

7.3 相互確認

関数	動作
`codes::compare_barcode_with_text()`	すべてのコードの内容が本文に現れれば真
`codes::validate_barcode_format(regex)`	全コードの内容が正規表現に一致すれば真
`codes::validate_barcode_position(region)` または `(x0, y0, x1, y1)`	全コードが領域内にあれば真

compare_barcode_with_text は業界で最も高くつくミスを捕まえます。バーコードがある製品を指しているのに、印刷された文字は別の製品を示している場合です。

check "Cross-checks" {
  assert codes::compare_barcode_with_text(),
    "the barcode number does not appear in the text — artwork with swapped data?"

  // EAN-13 のみ：ちょうど13桁
  assert codes::validate_barcode_format("^\d{13}$"),
    "there is a code outside the EAN-13 pattern"

  // 名前付き領域で指定すると読みやすくなります
  area = region(400, 20, 180, 80, "barcode area")
  assert codes::validate_barcode_position(area),
    "barcode outside the reserved area of the packaging"
}

7.4 完全な例